//dcpYXscans3d -  Obtain a 3D Double CP HY-YX-XX spectrum with 4scans ni = 32
//                increments and ni2 = 32 increments.     

//              Argument 1 is the action: 'setup', 'process' or 'plot'. The 
//              action 'setup' initiates an experiment.  The actions 'process'
//              and 'plot' are called by chempackQ. 

//              Argument 2 is the nucleus, 'C13' (only). The second nucleus is 
//              assumed to be 'N15'.

//              Argument 3 is the '13C' region, 'alpha' (alpha carbons) or 'carbonyl'
//              carbonyl carbons. The second region is assumed to be 'amide'. The 
//              region-code is 'NCa' for 'alpha' and 'NCO' for 'carbonyl'.

//              Argument 4 can be 'darr','c7', 'c7dqf','spc5' or 'spc5dqf to set 
//              mixing. 

//              Argument 5 is the mixing time for 'darr'or the number of cycles 
//              for 'c7'and 'spc5'. For 'c7dqf' and 'spc5dqf', dqfXc7= 'y' and 
//              dqfXspc5='y'and the number of cycles is 2*$5. 

//              Argument 6 is 'softpuly' for band-selctive d2. Soft-pulse parameters
//              are loaded from the probe file. 

//              Argument 7 is 'ctNy' for constant-time d3. t3Max is set automatically 
//              with a minimum of 3 ms. 

//              Argument 8 is 'ctdn' for *no* constant-time decoupling. For the default 
//              tRFmax is set automatically with a minimum of 5 ms. 

//              Argument 9 is 'spinal', 'tppm' or 'waltz' for dec2, Y-channel 
//              decoupling. The appropriate parameters are laoded from the probe file. 

//==================
// The SETUP macro
//==================

if (($#>0) and ($1='setup')) then   

// Set the Nuclei and Region

   rtppar('Settancpx')
   AhYXX

// Set the Observe Region for Pulsewidths, Acquisition and Decoupling.

   $reg='' $pwr='' $nuc=''
   $macroname = $0 + '(\'region\',$2,$3,$4,1):$reg,$pwr,$nuc'
   exec($macroname) 
   $pwr='' 

// Set the Decoupler-2 Region-code for HY CP and dec2.

   $macroname = $0 + '(\'region\',\'N15\',\'amide\',\'\',0):$reg1,$pwr1,$nuc1'
   exec($macroname) 
   $pwr1=''

// Set the Double-CP Region-code for YX CP

   if ($reg = 'HCa') then 
      $reg2 = 'NCa'
   else
      $reg2 = 'NCO'
   endif

// Get the Spinrate

   $macronamespin = $0 + '(\'spinrate\'):$srate'
   exec($macronamespin)   

// Calibrate setddrtc for CP

   exists('ddrpm','parameter'):$e
   if ($e < 0.5) then
      create('ddrpm','string')
      ddrpm='r'
   endif   
   rof2=rd-0.6 alfa=ad

// Obtain Pulsewidth Parameters from the Observe Region, $reg.

   probeparamgroup('getlocal',$reg,$nuc,'','ofX90','dbX90'):tof,tpwr
   probeparamgroup('get',$reg,$nuc,'90X','a','pw')
   probeparamgroup('getlocal',$reg,'H1','','ofX90','dbX90'):dof,dpwr
   probeparamgroup('get','hp'+$reg,'H1','90H','a','pw')

// Obtain the Decoupler 2 Pulse-Width parameters from $reg1.

   probeparamgroup('getlocal',$reg1,$nuc1,'','ofX90','dbX90'):dof2,dpwr2
   probeparamgroup('getlocal',$reg1,$nuc1,'90X','a','pw'):aY90,pwY90

// Obtain the HY CP Parameters from the Decoupler 2 Region, $reg1.

   probeparamgroup('getlocal',$reg1,'H1','HX','ch','sh','to','fr',
                                    'aH','b','d','t','of'):chHY,shHY,toHY,frHY,
                                    aHhy,bHY,dHY,tHY,ofHY
   probeparamgroup('getlocal',$reg1,$nuc1,'HX','aX'):aYhy

// Obtain Proton Decoupling Parameters from the Observe Region, $reg.
 
   probeparamgroup('get',$reg,'H1','tppmH','a','pw','ph')
   probeparamgroup('get',$reg,'H1','spinalH','a','pw','ph','alp')
   Hseq = 'spinal'

// Obtain DCP Parameters from the DCP region, $reg2.

   probeparamgroup('get',$reg2,$nuc1,'YX','ch','sh','to','fr',
                                    'aY','b','d','t','of')
   probeparamgroup('get',$reg2,$nuc,'YX','aX')
   probeparamgroup('get',$reg2,'H1','','aHyx')

// Set Acquisition/Display Parameters

   ph sw=10000 at=0.015 fn=4.0*np sb=at/2.0 sb='n' sbs=0.0 sbs='n' lb=0.0 lb='n' gain=30
   nt=4 ni = 32 sw1=5000.0*trunc(200.0*sfrq/5000.0+1.0) phase=1,2 fn1=256 pmode='full' phase2=1,2 fn2=256 ni2=32 
   sw2=5000.0 d1=0.5

// Automatic NUS

   SPARSE='n'nimax = ni stype='a'

   $nus='n'  
   if (SPARSE='y') and (stype='a') then $nus = 'y' endif

   if ($nus = 'y') then 
      CS_inf='y'
      CS_cln='y'
      CS_dpars='y'
      CSdnoise='y'
      CSthr=2.0
   endif

// Set Parameters for Mixing (default is 'darr', tXmix=200 aHmix=0.0 for Z-filter)

   mMix='darr'
   tXmix=200.0
   aHmix=0.0
   if ($# > 3) then 
      if ($4 = 'darr') then 
         tXmix = 0.0
         if ($# > 4) then 
            tXmix = $5
         endif
         aHmix = aH90*srate*4.0e-6*pwH90
         mMix = 'darr'
      elseif (($4 = 'c7') or ($4 = 'c7dqf')) then 
         qXc7 = 10
         if ($# > 4) then 
            qXc7 = $5
         endif
         aXc7 = 2000.0
         if (srate>500) then 
            $pwXc7 = 1.0e6/(7.0*srate)
            pwXc7 = 0.4*trunc($pwXc7/0.4 + 0.5)
            $srate = 1.0e6/(7.0*pwXc7)
//            sethw('spin', $srate, 'nowait')
            aXc7 = aX90*(4.0*pwX90)/pwXc7
            if (aXc7 >= 4095) then 
               write('error','dcpYXscans2d Error: aXc7 is >= to 4095')
               abort
            endif
         endif
         aHmixc7=aH90
         dqfXc7='n'
         if ($4 = 'c7dqf') then 
            dqfXc7 = 'y'
         endif
         mMix = 'c7'
      elseif (($4 = 'spc5') or ($4 = 'spc5dqf')) then
         qXspc5 = 10
         if ($# > 4) then 
            qXspc5 = $5
         endif
         aXspc5 = 2000.0
         if (srate>500) then 
            $pwXspc5 = 1.0e6/(5.0*srate)
            pwXspc5 = 0.1*trunc($pwXspc5/0.1 + 0.5)
            $srate = 1.0e6/(5.0*pwXspc5)
//            sethw('spin', $srate, 'nowait')
            aXspc5 = aX90*(4.0*pwX90)/pwXspc5
            if (aXspc5 >= 4095) then 
               write('error','dcpYXscans2d Error: aXspc5 is >= to 4095')
               abort
            endif
         endif
         aHmixspc5=aH90
         dqfXspc5='n'
         if ($4='spc5dqf') then 
            dqfXspc5 = 'y'
         endif
         mMix = 'spc5'
      endif
   endif

// Band-selective d2 Evolution 

   softpul='n'
   if ($# > 5) then 
      if ($6='softpuly') then 
         softpul='y'
         probeparamgroup('get',$reg,$nuc,'shp1X','wv','a','db','pw','of')
      endif 
   endif

// Constant-time d3 Evolution (default is 'n')

   ctN='n'
   t3max=0.0
   if ($#>6) then 
      if ($7='ctNy') then 
         ctN='y'
         t3max=3000.0 
      endif
   endif 

// Constant-time Decoupling (default is 'y')

   ctd='y'
   tRFmax=5000.0
   if ($#>7) then
      if ($8='ctdn') then
         ctd='n'
         tRFmax=0.0
      endif
   endif

// DEC2 Y-channel Decoupling (default is 'n')

   ddec2='n'
   if ($#>8) then 
      if ($9='spinal') then 
         ddec2='y'
         Yseq='spinal'
         probeparamgroup('get',$reg,$nuc,'spinalY','a','pw','alp','ph')
      elseif ($9='tppm') then
         ddec2='y'
         Yseq='tppm'
         probeparamgroup('get',$reg,$nuc,'tppmY','a','pw','alp','ph')
      elseif ($9='waltz') then
         ddec2='y'
         Yseq='waltz'
         probeparamgroup('get',$reg,$nuc,'waltzY','a','pw','alp','ph')
      endif
   endif
      
// Set the Auto Display to Null

   wnt = ''

// Set Macro-Specific Processing and Plotting 

   wexp = 'chempackQ'
   execprocess = $0 + '(\'process\',\''+$2+'\',\''+$3+'\',\''+$4+'\',0)'
   execplot = ''
//   au
   return
endif

//===========================
// Macro-Specific Processing
//===========================

if (($# > 0) and ($1 = 'process')) then 

// Analyze the 1H Nutation Curve

   $macroname = $0 + '(\'scans2dyx\',$2,$3,$4,0)'
   exec($macroname)  
endif

//===========================
// Macro-Specific Plotting
//===========================

if (($# > 0) and ($1 = 'plot')) then 
   wc = 50 sc = 50
   plot1d
   return  
endif 

//==================================
// Begin AutoCalibration Utilities
//==================================

//--------------------
// The maxamp function
//--------------------

if (($# > 0) and ($1 = 'maxamp')) then
   select(celem) 
   if (celem=1) then 
      vsadj($2) 
   endif
   peak:$ht
   if ($ht>$2) then 
      vsadj($2) 
   endif 
   return    
endif  

//--------------------------
// The  minmaxfit function
//--------------------------

if (($# > 0) and ($1 = 'minmaxfit')) then 

   $bestone=$2
   $lim=2
   if ($#>3) then $lim=$4 endif

// Prepare 'analyze.inp'

   $file=curexp+'/analyze.inp'
   exists($file,'file'):$a
   if ($a>0.5) then 
      write('reset',$file) 
   endif

   format((2*$lim+1),2,0):$sizes

   write('file',$file,'AMPLITUDE')
   write('file',$file,'INTENSITY')
   write('file',$file,'%12s%13s%7s%7s\n','1',$sizes,'linear','linear')
   format((2*$lim+1),2,0):$sizes
   write('file',$file,'%8s%5s','NEXT',$sizes)
   write('file',$file,'1')

   $step=$bestone-$lim
   repeat
      select($step)
      peak:$ht
      write('file',$file,'%14.1f%12.2f',$step,$ht)
      $step=$step+1
   until ($step>$bestone+$lim)

// 'poly2 Analysis with 'expfit'

   analyze('expfit','regression','poly2')
   $file=curexp+'/analyze.out'
   lookup('file',$file)
   lookup('seek','NEXT','skip', '2','read','4'):$a0s,$a1s,$a2s
   format($a0s,8,4):$a0
   format($a1s,8,4):$a1
   format($a2s,8,4):$a2
   $inf=-$a1/(2.0*$a2)
   $infval=$a0+$a1*$inf+$a2*$inf*$inf

// Mean Value from 'poly0' 

   analyze('expfit','regression','poly0')
   lookup('file',$file)
   lookup('seek','NEXT','skip', '2','read','4'):$a0s,$a1s,$a2s
   format($a0s,8,4):$a0
   $mean=$a0
//   write('line3','$inf=%f $infval=%f $mean=%f',$inf,$infval,$mean)
//   write('line3','$2 = %f',$2)

// Min ($minmax<0) or Max ($minmax>0) or none ($minmax=0)

   $minmax=0 $ret=0.0
   if (($bestone-$lim)<$inf)and($inf<($bestone+$lim)) then 
      $ret=$inf
      if ($infval<$mean) then 
         $minmax=-1
      else
         $minmax=1
      endif
   endif

//   write('line3','$xmin = %f $ret = %f $xmax = %f $minmax=%f',$bestone-$lim,$ret,$bestone+$lim,$minmax)

// Return the new $bestone and a Fraction After $bestone,
// else Return $bestone=$2 and $remainder=0.0 

   $remainder=0 
   if (($3='min')and($minmax<0)) then 
      $bestone=trunc($ret) 
      $remainder=$ret-$bestone
   endif
   if (($3='max')and($minmax>0)) then 
      $bestone=trunc($ret) 
      $remainder=$ret-$bestone
   endif
   if ($minmax=0) then
      $bestone=$2 
      $remainder=0.0
   endif
//   write('line3','$bestone=%f',$bestone)
   return($bestone,$remainder)
endif 

//---------------------
// The Scans2d YX Macro
//---------------------

if (($# > 0) and ($1 = 'scans2dyx')) then

// Set the Region

   $reg='' $pwr='' $nuc=''
   $macroname = $0 + '(\'region\',$2,$3,$4,0):$reg,$pwr,$nuc'
   exec($macroname)  
   $pwr=''

// Phase the Data
    
   fn=4.0*np sb='n' ph wft lp=4 vsadj(100) noislm(1.0)
   ds(1)
   aph0:$aphok
   if ($aphok=1) then
      aph0
      peak:$int
      if ($int<-10) then rp=rp+180 endif
   endif

// Select $ni and $ni2 and Set Linebroadening 

   $nus='n'
   if (SPARSE='y') and (stype='a') then $nus = 'y' endif

   $ni=ni
   if (nimax > ni) and ($nus='y') then 
      $ni=nimax
   endif
   lb1 = sw1/(3.14159*1.0*$ni)

   $ni2=ni2
   if (ni2max > ni2) and ($nus='y') then 
      $ni2=ni2max
   endif
   lb2 = sw1/(3.14159*1.0*$ni2)

   lb = 2.0*sw/(3.14159*np)

// Linear Prediction

   parlp
   proc='ft'

   parlp(1) proc1='lp' lpopt1='f' lpfilt1=8 lpnupts1=$ni-3 strtlp1=$ni lpext1=$ni strtext1=$ni+1

   parlp(2) proc2='lp' lpopt2='f' lpfilt2=8 lpnupts2=$ni2-3 strtlp2=$ni2 lpext2=$ni2 strtext2=$ni2+1

// Set 2D limits

   setref
   if ($reg = 'HCa') then 
      sp = 35.0*reffrq   
      wp = 50.0*reffrq   
   else
      sp = 165.0*reffrq   
      wp = 20.0*reffrq  
   endif
   setref1
   sp1 = 0.0*reffrq1
   wp1 = 200.0*reffrq1

   setref2
   sp1 = 90.0*reffrq2
   wp1 = 50.0*reffrq2

//2D Transform 

   if (page='XX2D') then 
      wft2da
      nm2d center dconi
      write('line3','XX-2D Projection')
   elseif (page='YX2D') then 
      wft2da('ni2')
      nm2d center dconi
      write('line3','YX-2D Projection')
   else
      write('line3','No Transform')     
   endif    
endif

//-------------------
// The Region Macro
//-------------------

if (($# > 0) and ($1 = 'region')) then
   $nuc=$2
   $reg=''
   $pwr=$4
   if (($# > 4) and ($5 = 1)) then 
      if ($2='C13') then 
         tn='C13' dn='H1' dn2='N15' dn3=''   
         wc = 200 sc =10
         ad=4.0 rd=4.0 ddrtc=8.0 rp=0 lp=0 ss=2 bs=4
         sw=100000.0 at=0.01 fn=16.0*np sb=at/2.0 sb='y' sbs='n' lb=0 lb='n' gain=30
         ofHX=0.0
         if ($3='alpha') then
            d1=2.0 nt=1
            setref setoffset('C13',60):tof tof=0.1*trunc(tof/0.1 + 0.5) sp=35p wp=50p
            $reg='HCa'
         elseif ($3='carbonyl') then 
            d1=2.0 nt=1
            setref setoffset('C13',175):tof tof=0.1*trunc(tof/0.1 + 0.5) sp=165p wp=20p
            $reg='HCO'
         elseif ($3='adam') then 
            d1=2.0 nt=1.0
            setref setoffset('C13',33.3):tof tof=0.1*trunc(tof/0.1 + 0.5) sp=28p wp=20p
            $reg='HC'
         endif
      elseif ($2='N15') then 
         tn='N15' dn='H1' dn2='C13'  dn3=''   
         wc = 200 sc =10
         ad=16.0 rd=4.0 ddrtc=20.0 rp=0 lp=0 ss=2 bs=4
         sw=100000.0 at=0.01 fn=16.0*np sb=at/2.0 sb='y' sbs='n' lb=0  lb='n' gain=30  
         ofHX=0.0
         if ($3='amide') then
            d1=2.0 nt=1
            setref setoffset('N15',115):tof tof=0.1*trunc(tof/0.1 + 0.5) sp=90p wp=50p
            $reg='HNai'
         elseif ($3='amine') then
            d1=2.0 nt=1 
            setref setoffset('N15',35):tof tof=0.1*trunc(tof/0.1 + 0.5) sp=15p wp=40p
            $reg='HNam'
         elseif ($3='amino') then 
            d1=2.0 nt=1
            setref setoffset('N15',35):tof tof=0.1*trunc(tof/0.1 + 0.5) sp=15p wp=40p
            $reg='HN'
         endif
         probeparamgroup('setlocal',$reg,$nuc,'','ofX90',tof)
      endif
   else
      if ($2='C13') then 
         if ($3='alpha') then
            $reg='HCa'
         elseif ($3='carbonyl') then 
            $reg='HCO'
         elseif ($3='adam') then 
            $reg='HC'
         endif
      elseif ($2='N15') then 
         if ($3='amide') then
            $reg='HNai'
         elseif ($3='amine') then 
            $reg='HNam'
         elseif ($3='amino') then 
            $reg='HN'
         endif
      endif
   endif

   return($reg,$pwr,$nuc)
endif

//---------------------
// The Spin Rate Macro
//---------------------

if (($# > 0) and ($1 = 'spinrate')) then

// Get the Current Spin Rate with an Average of 10

   banner('Measuring Spinning Rate and Stability')
   $count=1 srate=0
   repeat
      $index=''
      if ($count<10) then
         format($count,1,0):$index
      else
         format($count,2,0):$index
      endif
      $dest=curexp+'/stat'+$index
      shell('showstat > ',$dest):$dummy
 
      lookup('file',$dest,'currently', 'at:','read'):$masrate,$ret 
      if $ret then
         format($masrate,5,0):srate[$count]
      endif
//    echo($masrate)
      shell('sleep 1')
      $count=$count+1
   until ($count>10)

   averag(srate[1],srate[2],srate[3],srate[4],srate[5],srate[6],
       srate[7],srate[8],srate[9],srate[10]):$avgsrate,$dev

   $avgsrate = trunc($avgsrate + 0.5)  

//Check the Spin Rate 

   if ($avgsrate<500) then 
      $message='MAS Spin Rate Measurement is Less Than 500 Hz - Aborting with 0.0 '
      banner($message)
      srate = 0.0
      abort
   else
      srate = $avgsrate
   endif 

// Remove Files Generated by the Spin Rate Measurement

   $count=1
   repeat
      $index=''
      if ($count<10) then
         format($count,1,0):$index
      else
         format($count,2,0):$index
      endif
      $dest=curexp+'/stat'+$index
      rm($dest)
      $count=$count+1
   until ($count>10)
   return(srate)
endif 
