* MPC100X1 4X1 VIDEO MULTIPLEXER MACROMODEL
* REV.A   7/6/92   KL
*
*  ------------------------------------------------------------------------ 
* |  NOTICE: THE INFORMATION PROVIDED HEREIN IS BELIEVED TO BE RELIABLE;   |
* |  HOWEVER; BURR-BROWN ASSUMES NO RESPONSIBILITY FOR INACCURACIES OR     |
* |  OMISSIONS.  BURR-BROWN ASSUMES NO RESPONSIBILITY FOR THE USE OF THIS  |
* |  INFORMATION, AND ALL USE OF SUCH INFORMATION SHALL BE ENTIRELY AT     |
* |  THE USER'S OWN RISK.  NO PATENT RIGHTS OR LICENSES TO ANY OF THE      |
* |  CIRCUITS DESCRIBED HEREIN ARE IMPLIED OR GRANTED TO ANY THIRD PARTY.  |
* |  BURR-BROWN DOES NOT AUTHORIZE OR WARRANT ANY BURR-BROWN PRODUCT FOR   |
* |  USE IN LIFE-SUPPORT DEVICES AND/OR SYSTEMS.                           |
*  ------------------------------------------------------------------------ 
* CONNECTIONS:   IN 1
*                | IN 2
*                | | IN 3
*                | | | IN 4
*                | | | | SELECT 4
*                | | | | | SELECT 3
*                | | | | | |  POSITIVE SUPPLY
*                | | | | | |  |  OUPUT
*                | | | | | |  |  |  NEGATIVE SUPPLY
*                | | | | | |  |  |  |  SELECT 2
*                | | | | | |  |  |  |  |  SELECT 1
*                | | | | | |  |  |  |  |  |
.SUBCKT MPC100X1 1 3 5 7 8 9 10 11 12 13 14
**
X1  1 10 11 12 14  MUX1 ; One of four muxes
X2  3 10 11 12 13  MUX1 ; One of four muxes
X3  5 10 11 12  9  MUX1 ; One of four muxes
X4  7 10 11 12  8  MUX1 ; One of four muxes
**
C208    8  0   2E-12
C209    9  0   2E-12
C211   11  0   2E-12
C213   13  0   2E-12
C214   14  0   2E-12
**
.ENDS MPC100X1
* ONE OF FOUR CHANNELS OF THE VIDEO SIGNAL MULTIPLEXER
*            INPUT
*            |  NEGATIVE SUPPLY
*            |  |  OUTPUT
*            |  |  |  POSITIVE SUPPLY
*            |  |  |  |  SELECT
*            |  |  |  |  |
*            |  |  |  |  |
.SUBCKT MUX1 1 10 11 12 14
V22  22  0  1.5
V27  12 27  1.5
V28  28 10  1.5
**
G21  25 26  14 22  -87E-6
**
C23  23  0  2.0E-12
C24  23 11  0.1E-12
C25  25  0  0.6E-12
C26  26  0  0.6E-12
**
R21  14  0  40E3
R22  22  0  1E9
R23  23  0  1.3E6
R24  23  1  145
**
Q21  10 10 25  NI
Q22  26 26 12  NI
Q23  10 23 25  PI
Q24  12 23 26  NI
Q25  27 25 11  NI 4
Q26  28 26 11  PI 4
**
.MODEL NI NPN
.MODEL PI PNP
**
.ENDS MUX1