Как узнать хендл консольного окна?
делаю так
invoke GetStdHandle,STD_OUTPUT_HANDLE
но это не есть хендл консольного окна
программы... :-(

Что-то типа этого:

hwnd = GetWindow(GetDesktopWindow(), GW_CHILD);
while(hwnd){
GetWindowThreadProcessId(hwnd, &pid);
if (pid == GetCurrentProcessId()){
// окно найдено
}
hwnd = GetWindow(hwnd, GW_HWNDNEXT);
}

Andrey Ch
HOWTO: Obtain a Console Window Handle (HWND)

Спасибо за помощь

; Ну вот переписал под Фасм
;При каждом запуске разный хэндл в eax
;000002FC
;00000374
;000003A4
;У меня есть вопрос,
;Значении таких хэндлов это нормально?
;можно ли какой то утилитой посмотреть хендлы
;Может мне не верно выдает результат эта программа?


; FASM 1.45
; Хендл Консольного окна
; Obtaining a Console Window Handle (HWND)

format PE console

entry start


include '%inclfasm%\win32a.inc'

section '.data' data readable writeable


hwndFound dd 0 ; this is what is returned to the caller
pszNewWindowTitle: times 1024 db 0 ; contains fabricated WindowTitle
pszOldWindowTitle: times 1024 db 0 ; contains original WindowTitle
formatString db '%d/%d',0 ; takes a decimal "input" - %d
TickCount dd 0
CurrentProcessId dd 0


section '.code' code readable executable

start:

; fetch current window title


invoke GetConsoleTitle,pszOldWindowTitle,1024 ;




; format a "unique" NewWindowTitle

invoke GetCurrentProcessId
mov [CurrentProcessId], eax
invoke GetTickCount
mov [TickCount], eax


; wsprintf(pszNewWindowTitle,"%d/%d",
; GetTickCount(),
; GetCurrentProcessId());

invoke wsprintf,pszNewWindowTitle,formatString,[TickCount],[CurrentProcessId]
add esp,12


;change current window title

invoke SetConsoleTitle,pszNewWindowTitle


;ensure window title has been updated

invoke Sleep,40 ;

;look for NewWindowTitle

; hwndFound=FindWindow(NULL, pszNewWindowTitle);

invoke FindWindow,NULL,pszNewWindowTitle
mov [hwndFound], eax


;restore original window title

invoke SetConsoleTitle,pszOldWindowTitle


;returns the HWND -- or NULL if the operation failed.
mov eax, [hwndFound]


invoke ExitProcess,0

section '.idata' import data readable writeable

library kernel,'KERNEL32.DLL',\
user32,'USER32.DLL'

import kernel,\
GetConsoleTitle,'GetConsoleTitleA',\
GetTickCount,'GetTickCount',\
GetCurrentProcessId,'GetCurrentProcessId',\
SetConsoleTitle,'SetConsoleTitleA',\
Sleep,'Sleep',\
ExitProcess,'ExitProcess'

import user32,\
FindWindow,'FindWindowA',\
wsprintf,'wsprintfA'


;section '.rsrc' resource data readable

Нормально. Утилита:
http://comrade.shacknet.nu/tmp/winview.zip

Попробовал утилиту, HANDLE совпадают значит
прога работает нормально.
:-) Спасибо за помощь.