;абсолютно точное преобразование long_double в строку 
long_double_to_str:;(str +4, long_double +8, unused_word +18)
;размер строки должен быть 1+1+1+16383+63+1 байт
;результат:
;в str - символьное представление числа
;eax указывает на (последний записанный символ+1)
	push ebp
	push esi
	push edi	;+12
	mov edi,[12+esp+4]
;выделяем память, чтобы преобразовать lond_double в fixed_point_16416.16448
	mov ecx,4108/4
    .alloc:
	push 0		;+4120
	loop .alloc
	mov edx,[4120+esp+8+8]	;exponent
	test dx,dx
	jns .no_sign
	mov al,'-'
	stosb
    .no_sign:
;вычисляем на сколько нужно сдвинуть мантисту и куда ее записать
	and edx,7fffh	
	lea ecx,[edx+2]
	add edx,2
	and ecx,31
	and edx,-32
	shr edx,3
;сдвиг и запись
	xor eax,eax
	mov ebx,[4120+esp+8+4]
	shld eax,ebx,cl
	mov [esp+edx+8],eax
	mov eax,[4120+esp+8]
	shld ebx,eax,cl
	mov [esp+edx+4],ebx
	shl eax,cl
	mov [esp+edx],eax
	lea ebp,[esp+2056]
;преобразование целой части
	mov esi,2052
	xor eax,eax
	push -'0'
    .l0:	;отбрасывание ведущих нулей
	sub esi,4
	js .out_zero
    .l1:	
	xor eax,eax
	cmp dword [ebp+esi],eax
	jz .l0
	mov ecx,esi
	xor edx,edx
    .l2:	;делим целую часть на 10
	mov eax,[ebp+ecx]
	div [.c10]
	mov [ebp+ecx],eax
	sub ecx,4
	jns .l2
	push edx	;сохраняем цифру
	or eax,esi	
	jnz .l1		;если целая часть не ноль, то делим снова
    .l4:	;вывод цифр
	pop eax
    .out_zero:
	add al,'0'
	stosb
	jnz .l4
	dec edi
    .out_pt:
	mov al,'.'
	stosb
;преобразование дробной части
	mov esi,-2060
    .l6:	;отбрасывание завершающих нулей
 	add esi,4
	jns .exit
    .l8:
	cmp dword [ebp+esi],0
	jz .l6
	xor ebx,ebx
	mov ecx,esi
    .l7:	;умножаем дробную часть на 10
	mov eax,[ebp+ecx]
	mul [.c10]
	add eax,ebx
	adc edx,0
	mov [ebp+ecx],eax
	mov ebx,edx
	add ecx,4
	js .l7
	or eax,esi
	lea eax,[edx+'0']	;выводим цифру
	stosb
	jnz .l8		;если дробная часть не ноль, то умножаем снова
    .exit:
	cmp al,'.'
	jnz .l9
	dec edi
    .l9:
	mov byte [edi],0
	add esp,4108	;+12
	xchg eax,edi
	pop edi
	pop esi
	pop ebp		;+0
	ret 16
    .c10 dd 10