format PE GUI 4.0 DLL
entry DllEntryPoint
include '%include%\win32a.inc'
;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++;
section '.data' data writeable readable

  hHook        dd   0
  hInstance    dd   0
  hThread      dd   0
  hProcessID   dd   0
  hThreadID    dd   0
  lHandle      dd   0
  lpProcess    dd   0
  hStr	       db   'VOLOVIEW', 0 ;имя искомого процесса
  hStrb        db   'voloview', 0
;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++;
section '.code' code readable executable

 proc DllEntryPoint, hInst, wReason, lpReserved
    enter
    mov   ebx, [hInst]
    mov   [hInstance], ebx
    mov   eax, TRUE
    return
;-------------------------------------------------------------;
 proc CallBack, code, wparam, lparam ;непосредственно процедура
    enter			     ;хука
    cmp   [code], HC_ACTION
    jne   CallBackQuit
    mov   eax, [lparam]
    cmp   dword [eax + 4], $204
    je	  MMM
    cmp   dword [eax + 4], $205
    je	  MMM
    jmp   CallBackQuit
 MMM:
    mov   dword [eax + 4], 0	     ;патчится нужное событие
 CallBackQuit:
    invoke CallNextHookEx, [hHook],\
			   [code],\
			   [wparam],\
			   [lparam]
    return
;-------------------------------------------------------------;
 proc vveMouseHook, boolean ;экспортируемая dll-кой процедура
    enter		    ;которая устанавливает хук
    cmp   [boolean], TRUE
    jne   KillHook
    call  FindVoloview	    ;поиск процесса voloview и
    cmp   [hThread], 0	    ;дескриптора нужного потока в нем
    je	  BadQuit
    invoke SetWindowsHookEx, WH_GETMESSAGE,\ ;ставится ху...
			     CallBack,\
			     [hInstance],\
			     [hThread]
    cmp   eax, 0
    je	  BadQuit
    mov   [hHook], eax
    jmp   GoodQuit
 KillHook:
    invoke UnhookWindowsHookEx, [hHook]      ;киляется...
    cmp    eax, TRUE
    je	   GoodQuit
 BadQuit:
    mov   eax, FALSE
    return
 GoodQuit:
    mov   eax, TRUE
    return
;-------------------------------------------------------------;
 proc FindVoloview
    enter
    invoke GetProcessHeap
    invoke HeapAlloc, eax,\ ;заполняется описанием процесса при
		      HEAP_ZERO_MEMORY,\ ;вызове Process32Next
		      $128
    mov    [lpProcess], eax
    mov    ebx, [lpProcess]
    mov    word [ebx], $128 ;первый параметр - размер структуры
    invoke CreateToolhelp32Snapshot, $6, 0 ;типа "снимок" процессов
    mov    [lHandle], eax
    invoke Process32First, [lHandle], [lpProcess]
FindProcess:
    invoke Process32Next, [lHandle], [lpProcess]
    cmp    eax, FALSE
    je	   ExitCikl
    mov    edx, [lpProcess]
    add    edx, $24    ;по данному смещению лежит строка с именем
    call   FindStroka  ;exe-шника под 2k, либо с полным путем
    cmp    eax, TRUE   ;к оному под 98.
    jne    FindProcess
    mov    edx, [lpProcess]
    mov    eax, [edx + 8]    ;а здесь - ID процесса
    mov    [hProcessID], eax ;по которому выделяеш поток
    mov    eax, TRUE
ExitCikl:
    cmp    eax, FALSE
    je	   ExitFin
    mov    eax, [lpProcess]
    mov    dword [eax], 1Ch
    invoke Thread32First, [lHandle], [lpProcess]
NextThread:
    invoke Thread32Next, [lHandle], [lpProcess]
    cmp    eax, FALSE
    je	   ExitFin
    mov    ebx, [lpProcess]
    mov    eax, [ebx + 0Ch] ;ID процесса, которому принадлежит поток
    cmp    eax, [hProcessID]
    jne    NextThread
    mov    eax, [ebx + 8]   ;дескриптор нужного потока
    mov    [hThread], eax
ExitFin:
    invoke GetProcessHeap
    invoke HeapFree, eax,\
		     0,\
		     [lpProcess]
    invoke CloseHandle, [lHandle]
    return
;---------------------поиск подстроки-------------------------;
proc FindStroka
    enter
      ;ну здесь и ищу в переданной строке имя своего
      ;процесса... Ввиду стрААшной кривизны того, что здесь
      ;было написано и нынешней тенденции "тотальной оптимизации",
      ;стыжусь показывать :)))
    return
;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++;
section '.idata' import data readable writeable

 library kernel, 'kernel32.dll',\
	 user, 'user32.dll'

 import kernel,\
	CreateToolhelp32Snapshot, 'CreateToolhelp32Snapshot',\
	Process32First, 'Process32First',\
	Process32Next, 'Process32Next',\
	Thread32First, 'Thread32First',\
	Thread32Next, 'Thread32Next',\
	CloseHandle, 'CloseHandle',\
	GetProcessHeap, 'GetProcessHeap',\
	HeapAlloc,'HeapAlloc',\
	HeapFree,'HeapFree'
 import user,\
	SetWindowsHookEx, 'SetWindowsHookExA',\
	UnhookWindowsHookEx, 'UnhookWindowsHookEx',\
	CallNextHookEx, 'CallNextHookEx'
;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++;
section '.edata' export data readable writeable

 export 'Mouse.dll',\
	vveMouseHook, 'vveMouseHook'
;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++;
section '.reloc' fixups data readable discardable
;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++;